1000 rem "EBBS 64 Config Maker
1010 rem "Written by Ed Parry
1020 rem "Update : 870728
1030 :
1040 rem "List this program, setup
1050 rem "configs as desired then
1060 rem "run it to write config file.
1070 :
1080 mt=3:rem modem type
1090 rem 1 = cbm's 1650 or compatible
1100 rem 2 = cbm's 1670 (300/1200)
1110 rem 3 = telbbs server
1120 rem 4 = wimodem
1130 ifmt=1thenri=0:ca=0:aa=0:ok=32:ms=0
1140 ifmt=2thenri=0:ca=0:aa=1:ok=32:ms=0
1150 ifmt=3thenri=0:ca=16:aa=0:ok=6:ms=32
1160 ifmt=4thenri=0:ca=0:aa=1:ok=6:ms=0
1170 :
1180 rem ri=ring indicator/either 8/0
1190 rem ca=carrier detect/either 16/0
1200 rem aa=auto answer/0=auto/1=manual
1210 rem ok=modem primer/try 6,32 or 38
1220 rem ms=modem speed/either 32/0
1230 :
1240 os=02:rem open/closed system flag
1250 rem 0  = closed system
1260 rem 1  = looky loo:no post/email/feedback
1270 rem 2  = looky loo 2:feedback ok
1280 rem 'os' equals new users level
1290 rem see also 'levels'
1300 :
1310 rem system levels - add values
1320 rem use ebbs level calc to figure
1330 rem levels when in the userfile editor.
1340 rem enter '*' to calc a level.
1350 rem enter '?' to display access.
1360 rem following info is fyi only.
1370 :
1380 rem 0 - no access at all
1390 rem 1 - read only 1:mb1/no post/email
1400 rem 2 - read only 2:mb1/feedback ok
1410 rem 4 - msg base 1
1420 rem 8 - msg base 2
1430 rem 16 - msg base 3
1440 rem 32 - msg base 4
1450 rem 64 - msg base 5
1460 rem 128 - xfer 1
1470 rem 256 - xfer 2
1480 rem 512 - xfer 3
1490 rem 1024 - xfer 4
1500 rem 2048 - xfer 5
1510 rem 4096 - 99 lines/no post limit
1520 rem 8192 - no time limit
1530 rem 16384 - sysop access
1540 :
1550 xf=0:rem xfer open/closed flag
1560 rem 0 = xfer open
1570 rem 1 = xfer closed
1572 :
1573 ua=0 : rem uploads denied/allowed
1574 rem 0 = uploads denied
1575 rem 1 = uploads allowed
1580 :
1590 au=1:rem update dl files flag
1600 rem 0 = update dl files manually
1610 rem 1 = system updates dl files
1620 :
1630 d1=08:rem email drive
1640 :
1650 hd(1)=08:rem msg base 1 drive
1660 hd(2)=08:rem msg base 2 drive
1670 hd(3)=08:rem msg base 3 drive
1680 hd(4)=08:rem msg base 4 drive
1690 hd(5)=08:rem msg base 5 drive
1700 :
1710 xd(1)=08:rem xfer section 1 drive
1720 xd(2)=08:rem xfer section 2 drive
1730 xd(3)=08:rem xfer section 3 drive
1740 xd(4)=08:rem xfer section 4 drive
1750 xd(5)=08:rem xfer section 5 drive
1760 :
1770 rem *143 dir entrys per drive*
1780 :
1790 mb%=5:rem # of active msg bases
1800 :
1810 td=08:rem text files drive
1820 :
1830 mm(1)=40:rem msg base 1 capacity
1840 mm(2)=10:rem msg base 2 capacity
1850 mm(3)=10:rem msg base 3 capacity
1860 mm(4)=10:rem msg base 4 capacity
1870 mm(5)=10:rem msg base 5 capacity
1880 :
1890 po(1)=3:rem max posts/mb1
1900 po(2)=2:rem max posts/mb2
1910 po(3)=2:rem max posts/mb3
1920 po(4)=2:rem max posts/mb4
1930 po(5)=2:rem max posts/mb5
1940 :
1950 tl%=45:rem online time limit
1960 :
1970 rem msg base names
1980 mb$(1)="Public Discussion"
1990 mb$(2)="C64/C128"
2000 mb$(3)="Programming"
2010 mb$(4)="Friends"
2020 mb$(5)="Sysops"
2030 :
2040 rem sysop name
2050 sy$="SYSTEM OPERATOR"
2060 :
2070 rem bbs name
2080 bn$="EBBS 64"
2090 :
2100 rem bbs city
2110 ci$="EBBS HEADQUARTERS"
2120 :
2130 rem dl section names
2140 dl$(1)="C64"
2150 dl$(2)="C128"
2160 dl$(3)="AMIGA"
2170 dl$(4)="CP/M"
2180 dl$(5)="MISC"
2190 :
2200 print"“nh";:cr$=chr$(13):poke53280,6:poke53281,1
2210 print"šr                                        ";
2220 print"r       EBBS 64 Config File Maker        ";
2230 print"r                                        ";
2240 print"r      EBBS 64 written by Ed Parry       ";
2250 print"r                                        "
2260 printtab(8)"‘(1) Help/Information"
2270 printtab(8)"‘(2) Write Config File"
2280 printtab(8)"‘(3) Edit EBBS Config's"
2290 printtab(8)"‘(4) Test for Modem Settingsš":print
2300 :
2310 geta$:ifa$=""then2310
2320 ifa$="1"then2530
2330 ifa$="2"then2370
2340 ifa$="3"thenlist1000-1060:end
2350 ifa$="4"then2760
2360 goto2310
2370 print"q INSERT SYSTEM FILES DISK/PRESS RETURN"
2380 geta$:ifa$<>chr$(13)then2380
2390 print"q      £Writing EBBS 64 config file"
2400 open1,8,2,"@0:cfg.64,s,w":r$=chr$(13)
2410 print#1,mt:print#1,ri:print#1,ca:print#1,aa:print#1,ok
2420 print#1,ms:print#1,os:print#1,xf:print#1,au
2430 print#1,d1:fori=1to5:print#1,xd(i):next
2440 fori=1to5:print#1,hd(i):next
2450 print#1,mb%:print#1,td
2460 fori=1to5:print#1,mm(i):next
2470 fori=1to5:print#1,po(i):next
2480 print#1,tl%
2490 fori=1to5:print#1,mb$(i):next
2500 print#1,sy$cr$bn$cr$ci$
2510 fori=1to5:print#1,dl$(i):next
2515 print#1,ua
2520 close1:print"qq       EBBS config file created.":end
2530 print"“        œEBBS HELP - Setting up:"
2540 print"q1 - Run 64 filemaker."
2550 print"2 - List/edit/resave/run this program."
2560 print"3 - Run EBBS/Setup files (ob, id, etc)
2570 print"4 - Look around. When ready, go ONLINE!"
2580 print"5 - Send big bucks/precious metals."
2590 print"qEBBS is freeware in compiled form."
2600 print"Please feel free to pass it around"
2610 print"and/or make freeware donations."
2620 print"qEBBS 64 basic code, ml source code,"
2630 print"doc's & registration is $40."
2640 print"qOrders (COD Okay)/Questions:"
2650 print"qEd Parry/EBBS64"
2660 print"8711 Langdon St. #8"
2670 print"Sepulveda, CA 91343"
2680 print"818-891-9350 - voice - 12-6pm"
2690 print"818-846-8083 - COREWARS EBBS (#2)":print"GEnie mailbox :EBBS"
2700 printtab(8)"qPress RETURN to continue";
2710 geta$:ifa$<>chr$(13)then2710
2720 run
2730 open2,8,2,"con*,s,r"
2740 get#2,a$:printa$;:ifst=0then2740
2750 close2
2760 rem test for modem settings
2770 print"“r                                        ";
2780 print"r   Please note that I cannot determine  ";
2790 print"r    the MANY possible combinations of   ";
2800 print"r RS232 interfaces and modems. This test ";
2810 print"r    will ONLY be as accurate as your    ";
2820 print"r        equipment will allow.           ";
2830 print"r                                        "
2840 print"šInsure that your modem and/or interface"
2850 print"is plugged in and turned on.":printspc(10)"qHit £RETURNš when ready"
2860 geta$:ifa$=""then2860
2870 open1,2,3,chr$(6)+chr$(0):rem setup rs232 port
2880 a=peek(56577)and8:ifa=8thena=0
2890 b=peek(56577)and16:ifb=16thenb=0
2900 c=peek(56577)and32:ifc=32thenc=0
2910 print"qRI - (RING INDICATOR) :"a
2920 print"CA - (CARRIER DETECT) :"b
2930 print"MS - (MODEM SPEED)    :"c
2940 print"AA = 0 if line 12/pin J supported"
2950 print"AA = 1 if line 12/pin J NOT supported"
2960 print"AA determines callers baud rate."
2970 print:printspc(10)"Hit £RETURNš to continue"
2980 geta$:ifa$<>chr$(13)then2980
2990 run